VB5 初級生 老怪範例(八)

回首頁

Home

分類

標題

大意

作者

日期
使用說明 VB5 初級生範例使用說明 　 老怪 1999/3/30
Timer 操作 沒有事件發生要如何偵測 時間是永遠不停的事件 老怪 1998/12/3
Scroll 操作 用 Scroll 物件改變 TextBox 值 　 老怪 1998/12/12
PictureBox MTV 歌詞模擬 把文字當成圖形處理 老怪 1998/12/12
TextBox 如何把字串對齊中央 有條件的 Alignment 老怪 1999/1/26
使用者界面 左右鍵同按的偵測 Button=3 難以成立 老怪 1998/12/10
使用者界面 偵測控制鍵的事件程序 KeyAscii 和 KeyCode 老怪 1999/1/30
視窗界面 控制項昇陷效果模擬 Form.Line 操作 老怪 1998/12/12
視窗界面 輸出一行多彩字串 CurrentX & CurrentY 的利用 老怪 1999/2/25
視窗界面 把圖片從一個表單拖到另一表單 OleDrag 命令群 老怪 1999/2/26
圖形處理 將 Long Value Color 換成 RGB 值 　 老怪 1999/1/12
變數處理 向 ActiveX 傳陣列資料 　 老怪 1998/12/11
變數處理 在一堆數值理選最大數 　 老怪 1998/12/11
變數處理 用 Collection 取代動態陣列 　 老怪 1998/12/29
變數處理 TextBox 的 Undo 動作模擬 用變數記錄舊資料 老怪 1999/1/15
變數處理 動態陣列的宣告及新增 　 老怪 1999/2/28
集合物件 在集合物件中找出特殊設定之子項 For Each ... In 敘述 老怪 1999/2/25
數值處理 求最大公因數與最小公倍數 　 老怪 1998/12/22
數值處理 在固定的集合裡隨機取出數值 　 老怪 1999/1/27
File I/O 循序檔及隨機檔之初議 　 老怪 1999/1/7
File I/O 用 InputB() 快速開中文檔 配合 StrConv 函數 老怪 1999/1/12

VB5 初級生範例使用說明

  1. 本範例歡迎非營利性個人及組織轉載使用，營利之利用請先徵得本人之同意，來信註明使用方式及回覆地址。
  2. 本範例所有的程式碼範例，皆屬十分基本的 VB 語法，如果您是個 VB User ，歡迎直接引用或改寫使用在你的程式中 ，本人不主張著作權，因為，沒辦法查嘛。
  3. 如果你是個 VB 初學者，又有點窮窮(和老怪一樣)，趕快把本頁另存新檔到你自己的磁碟，離線後慢慢看，也可以 Copy 給朋友喔(不可以收錢)。
  4. 本範例都是老怪幾個月來在 tw.bbs.comp.language 討論群組中回答版友問題的合輯，因為是針對問題解決，所以並沒有全面觀念的解說，不適合作為入門文章，但如果你讀了入門書，或是上了老師的課，心中仍不甚明白的話，就可以來這找找有沒有你要的答案，因為這都是別人問過的問題。
  5. 本人才疏學淺，之所以大膽公佈此範例，用意在自曝其短，希望遇到真正的行家可以加以指正，如果本篇有誤，請不吝來函告知。
  6. 我的電子郵件地址：letsgo@ms6.url.com.tw 。

回索引

沒有事件發生要如何偵測

Young Team Inc

若子畫面中使用者不在使用，想在某個時間(如卅秒)跳入母畫面，我知道用 Timer 可達到此目的，但我不知道用那個指令來偵測鍵盤及滑鼠，請予解惑。

老怪答：

  1. 使用一變數隨時間而遞增。
  2. 當變數到達某值表示條件成立。
  3. 接收到按鍵或滑鼠動作則重設變數初始值。
  4. 在表單上執行下列程式看看。沒有任何按鍵或滑鼠動作，30 秒後會自動 Unload。
    Option Explicit
    Dim Waiting As Integer
    Private Sub Form_Click()
        Waiting = 0
    End Sub
    Private Sub Form_KeyPress(KeyAscii As Integer)
        Waiting = 0
    End Sub
    Private Sub Form_Load()
        '每 1/10 秒驅動一次
        Timer1.Interval = 100
    End Sub
    Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single,
    Y As Single)
        Waiting = 0
    End Sub
    Private Sub Form_Unload(Cancel As Integer)
        Waiting = 0
    End Sub
    Private Sub Timer1_Timer()
        If Waiting > 300 Then
            Unload Me
        Else
            Waiting = Waiting + 1
        End If
    End Sub

回索引

左右鍵同按的偵測

穿山甲 撰寫於文章

請問在VB 中要如何判斷滑鼠左右鍵同時按？就像踩地雷遊戲中那樣。我知道用mousedown事件可以判斷是按左鍵還是按右鍵，但要如何判斷同時按呢？Button參數用3（左鍵+右鍵）好像也不行。

老怪答：

  1. 因為那怕你快手如快槍手傑西，在電腦的偵測下，還是不可能有左右鍵同時按下的情況，一般所說的兩鍵同按，在電腦的解讀，其實是先後按下左右鍵的意思。所以 Button參數用3（左鍵+右鍵）是一個理論上存在，實際很難在使用者操作十發生的狀況。
  2. So ，試試下面這一段：
    Option Explicit
    Dim OldButton As Byte
    Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single,
    Y As Single)
        If Button = 3 Then
            '因為兩鍵同時按下非常人能為，所以 Print "SupperMan"
            '實際上和 BingGo 要執行同一程序才對
            Print "Supper Man"
        Else
            If OldButton + Button = 3 Then
                Print "BingGo"
            End If
            OldButton = Button
        End If
    End Sub
    Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y
    As Single)
        OldButton = 0
    End Sub

回索引

向 ActiveX 傳陣列資料

diohsu 撰寫於文章

我正在設計一個控制項,可是始終無法傳一個二維陣列給控制項,有何良策可供參考!!!!

老怪答：

  1. 與陣列幾維無關，而是向 ActiveX 傳陣列本身的限制，我的測試如下：

回索引

控制項昇陷效果模擬

寄件者: Scott

label或其他物件設定失效時並不是變成灰色，而是像陷下去的模型一般。

老怪答：

'測試本範例請於 Form 上布置 Command1,2,3、Label1。

Option Explicit
Private Const FORM_CONTROL_FLATE = 0
Private Const FORM_CONTROL_UP = 1
Private Const FORM_CONTROL_DOWN = 2
Dim ShowMode As Byte
Private Sub Command1_Click()
    ShowMode = 1
    ObjectShowMode Label1, ShowMode
End Sub
Private Sub ObjectShowMode(varControl As Control, ByVal varMode As Byte)
Dim PWidth As Single
Dim x, y, rx, dy As Single
Dim UpValue As Long, DownValue As Long
    Select Case varMode
        Case FORM_CONTROL_FLATE
            UpValue = Me.BackColor
            DownValue = Me.BackColor
        Case FORM_CONTROL_UP
            UpValue = RGB(255, 255, 255)
            DownValue = RGB(0, 0, 0)
        Case FORM_CONTROL_DOWN
            UpValue = RGB(0, 0, 0)
            DownValue = RGB(255, 255, 255)
    End Select

    PWidth = ScaleX(1, vbPixels, Me.ScaleMode)

    x = varControl.Left - PWidth
    y = varControl.Top - PWidth
    rx = varControl.Left + varControl.Width + PWidth
    dy = varControl.Top + varControl.Height + PWidth

    Me.Line (x, y)-(rx, y), UpValue
    Me.Line (rx, y)-(rx, dy), DownValue
    Me.Line (rx, dy)-(x, dy), DownValue
    Me.Line (x, dy)-(x, y), UpValue
End Sub
Private Sub Command2_Click()
    ShowMode = 0
    ObjectShowMode Label1, ShowMode
End Sub
Private Sub Command3_Click()
    ShowMode = 2
    ObjectShowMode Label1, ShowMode
End Sub
Private Sub Form_Load()
    Command1.Caption = "Label Enable"
    Command2.Caption = "Label Flate"
    Command3.Caption = "Label Unable"

    Label1.Caption = "Label Control 昇陷測試"
End Sub

回索引

用 Scroll 物件改變 TextBox 值

寄件者: Scott

textbox右邊有上下紐可以調整其數值，亦可直接輸入。

老怪答：

'測試本範例請於 Form 上布置 Text1、VSroll1。

Option Explicit
Private Sub Form_Load()
    VScroll1.Max = 100
    VScroll1.Min = 0
    VScroll1.SmallChange = 1
    VScroll1.LargeChange = 1

    VScroll1.Value = 50
End Sub
Private Sub Text1_Change()
Static OldValue As Integer
    If Val(Text1.Text) > VScroll1.Max Or Val(Text1.Text) < VScroll1.Min Then
        Text1.Text = OldValue
    Else
        OldValue = Val(Text1.Text)
        VScroll1.Value = Val(Text1.Text)
    End If
End Sub
Private Sub Text1_KeyPress(KeyAscii As Integer)
    'KeyAscii 32 以下是一些控制鍵，攔截會造成操作障礙
    If KeyAscii >= 33 Then
        If KeyAscii <= vbKey9 And KeyAscii >= vbKey0 Then
        Else
            '把 KeyAscii 設為 0 就是取消輸入
            KeyAscii = 0
            MsgBox "不可輸入非數字字元"
        End If
    End If
End Sub
Private Sub VScroll1_Change()
    Text1.Text = VScroll1.Value
End Sub

回索引

MTV 歌詞模擬

小紀 撰寫於文章

如果大家有去MTV唱歌時,會發覺螢幕的歌詞會隨著歌聲曲調，而改變,我嘗試要去設計,用二個LABEL相疊,一個文字是黑色，一個是藍色,黑色的LABEL在上面,RUN時,黑色的LABEL會縮小，透出藍色的LABEL,達成歌詞變藍的效果,但可惜的是會閃爍，不曉得有無其他元件可做此功能。

老怪答：

  1. 在電腦上秀字基本上是全字一次秀，不可能有秀二分之一或四分之一字型的可能，但 MTV 螢幕畫面卻是將一個字一部份一部份呈現出來，是何原理呢？
  2. 其實我們在用 Windows 小畫家時卻可以在畫布上輸出文字，而變成一種點陣圖，一但文字變成一種圖形影像，就可以用選取工具選取二分之一或四分之一個字的影像。
  3. 所以我們就可以用這原理，使用一個 PictureBox 當文字影像轉換盒，用 Picture.Print 輸出文字到 PictureBox 上，再利用 PaintPicture 方法中的區塊取圖及透明貼圖的技巧，把文字影像貼到 MTV 螢幕上。
  4. 下面這段你可參考看看。
    '執行本範例請於 Form 上布置 Picture1,2、Timer1
    Option Explicit
    '顯示字串
    Dim ShowString As String
    '顯示字型大小
    Dim StringSize As Integer
    '字串高度及寬度
    Dim BWidth As Single, BHeight As Single
    '字串在 PictureBox 出現位置
    Dim ShowX As Single, ShowY As Single
    '變色字每次增長的寬度
    Dim InCrease As Single
    Private Sub Form_Load()
        With Picture1
            .AutoSize = True
            '此處暫時以一圖片代替 MTV 畫面
            .Picture = LoadPicture("c:\test\068.jpg")
        End With
        StringSize = 20
        ShowString = "塵緣如夢，幾番起伏總不平，到如今都成煙雲。"
        Picture1.FontSize = StringSize
        Picture2.FontSize = StringSize
        Picture2.Visible = False
        '設定變色字每次增長寬度為五分之一個字
        InCrease = ScaleX(StringSize, vbPixels, Picture2.ScaleMode) / 5
        '0.2 秒執行一次
        Timer1.Interval = 100
    End Sub
    Private Sub Picture1_Paint()
        Picture1.Cls
        '執行 MTV 秀字程式
        FirstShow ShowString
    End Sub
    Private Sub Picture1_Resize()
        '依圖片大小調整 PictureBox 及 Form 大小
        With Picture1
            .Move Me.ScaleLeft, Me.ScaleTop
            Me.Width = .Width + Me.Width - Me.ScaleWidth
            Me.Height = .Height + Me.Height - Me.ScaleHeight
        End With
    End Sub
    '繪製第一層白字的自訂程序
    Private Sub FirstShow(ByVal varString As String)
        With Picture2
            '算字串長度及寬度
            BWidth = .TextWidth(varString)
            BHeight = .TextHeight(varString)
            '把 Picture2 設為同於字串長度及寬度
            .Width = BWidth + .Width - .ScaleWidth
            .Height = BHeight + .Height - .ScaleHeight
            '黑底白字
            .ForeColor = RGB(255, 255, 255)
            .BackColor = RGB(0, 0, 0)
        End With
        '打開 AutoRedraw 功能以便取得 Image
        Picture2.AutoRedraw = True
        Picture2.Cls
        '把字串輸出到 Picture2 上
        Picture2.Print varString
        With Picture1
            '把字串輸出到畫面底部的中央位置
            ShowX = (.ScaleWidth - BWidth) / 2
            ShowY = .ScaleHeight - BHeight * 2
            '用目的圖 Or 來源圖方式把字串影像貼到圖片上，目的在只貼白字部份，
            '黑底不貼上。
            .PaintPicture Picture2.Image, ShowX, ShowY, , , , , , , vbSrcPaint
        End With
        '執行更換字顏色程序
        ChangeWordColor varString
    End Sub
    '繪製第二層藍字的自訂程序
    Private Sub ChangeWordColor(ByVal varString As String)
        With Picture2
            '白底藍字
            .ForeColor = RGB(0, 0, 255)
            .BackColor = RGB(255, 255, 255)
        End With
        Picture2.Cls
        '把字串輸出到 Picture2 上
        Picture2.Print varString
        '關掉 AutoRedraw 以節用系統資源
        Picture2.AutoRedraw = False
        '打開時間驅動器
        Timer1.Enabled = True
    End Sub
    Private Sub Timer1_Timer()
    '貼第二層藍字的寬度
    Static GetWidth As Single
        '每次增加 1/5 字寬顯示
        GetWidth = GetWidth + InCrease
        With Picture1
            '與先前貼圖不同是:
            '1.此處不是一次把整個 Picture2 中的字串影像一次貼上，而是逐步加寬影像範圍。
            '2.剛才貼圖方式是目的圖 Or 來源圖，此處則是目的圖 And 來源圖，目的在只貼
            '藍字，而不貼白背景。
            .PaintPicture Picture2.Image, ShowX, ShowY, , , , , GetWidth,Picture2.ScaleHeight, vbSrcAnd
        End With
        '如果取圖寬度大或等於字串寬度
        If GetWidth >= Picture2.ScaleWidth Then
            GetWidth = 0
            Picture1.Cls
            Timer1.Enabled = False
            Unload Me
        End If
    End Sub

回索引

在一堆數值理選最大數

herculez 撰寫於文章

Visual Basic 5.0 輸入 A,B,C 三值，要判段那一個最大，要用到那一個函數。

老怪答：

自己寫一個好了，試下面這一段，比一大串數字都可以

Option Explicit
Private Sub Form_Click()
Dim a, b, c
    a = 1
    b = 3
    c = 5

    Print GotMax(a, b, c)
End Sub
Private Function GotMax(ParamArray varArray() As Variant) As Long
Dim MaxNum As Double
Dim I As Long

    MaxNum = varArray(0)
    For I = 1 To UBound(varArray)
        If varArray(I) > MaxNum Then MaxNum = varArray(I)
    Next

    GotMax = MaxNum
End Function

回索引

求最大公因數與最小公倍數

Option Explicit

Private Function 最大公因數(ParamArray NumSerial() As Variant) As Long
Dim MinNum As Long, ReturnNum As Long
Dim I As Long, J As Long
Dim IsMin As Boolean
    MinNum = NumSerial(0)
    '最大公因數不可大於傳入序列數字之最小值
    For I = 0 To UBound(NumSerial)
        If NumSerial(I) < MinNum Then MinNum = NumSerial(I)
    Next

    For I = 1 To MinNum
        IsMin = True
        For J = 0 To UBound(NumSerial)
            If NumSerial(J) Mod I <> 0 Then
                IsMin = False
                Exit For
            End If
        Next

        If IsMin Then
            ReturnNum = I
        End If
    Next

    最大公因數 = ReturnNum
End Function

Private Function 最小公倍數(ParamArray NumSerial() As Variant) As Long
Dim MaxNum As Long, ReturnNum As Long
Dim I As Long
Dim IsMax As Boolean
    MaxNum = NumSerial(0)
    '最小公倍數要大於傳入序列數字之最大值
    For I = 0 To UBound(NumSerial)
        If NumSerial(I) > MaxNum Then MaxNum = NumSerial(I)
    Next

    Do
        IsMax = True
        For I = 0 To UBound(NumSerial)
            If MaxNum Mod NumSerial(I) <> 0 Then
                IsMax = False
                Exit For
            End If
        Next

        If IsMax Then
            ReturnNum = MaxNum
            Exit Do
        Else
            MaxNum = MaxNum + 1
        End If
    Loop

    最小公倍數 = ReturnNum
End Function

Private Sub Form_Click()
    Print 最大公因數(36, 48, 60)
    Print 最小公倍數(36, 48, 60)
End Sub

回索引

用 Collection 取代動態陣列

boncat 撰寫於文章

VB宣告陣列太大，dim  p(11-120,120,120,121) as single，程式在宣告階段就會出現記憶體不足，又動態宣告只能變動末維的數字，因我程式實際需要的陣列是如下依序增加的型態(先前陣列內容值都需保留)， 並非每次都需要用到每維的上界(120)，有何方法依序替陣列增胖？？

老怪答：

你可以考慮改用 Collection 物件變數，程式碼如下：

Option Explicit

Dim FirstCol As Collection
Dim SecondCol As Collection
Dim ThirdCol As Collection
Dim FourthCol As Collection

'顯示集合元素
Private Sub Form_Click()
    Print FirstCol.Item(1).Item(1).Item(1).Item(1)
    Print FirstCol.Item(1).Item(1).Item(1).Item(2)
    Print FirstCol.Item(1).Item(1).Item(2).Item(1)
    Print FirstCol.Item(1).Item(1).Item(2).Item(2)
End Sub

'為集合物件加入元素
Private Sub Form_Load()
    Set FourthCol = New Collection

    FourthCol.Add "FourthA1"
    FourthCol.Add "FourthB1"

    Set ThirdCol = New Collection
    ThirdCol.Add FourthCol

    Set FourthCol = New Collection
    FourthCol.Add "FourthA2"
    FourthCol.Add "FourthB2"
    ThirdCol.Add FourthCol

    Set SecondCol = New Collection
    SecondCol.Add ThirdCol

    Set FirstCol = New Collection
    FirstCol.Add SecondCol
End Sub

回索引

循序檔及隨機檔之初議

浪人 撰寫於文章

請問一下什麼是循序檔????在vb上怎麼把循序檔的內容讀出來...??

老怪答：

我覺得許多人對循序檔及隨機檔的觀念有些誤解，所以我想說說我的觀念，有不妥當地方請大家指教。

許多人都以為循序檔是一種排列有次序的結構化檔案，而隨機檔則是隨意放置，沒有次序及結構的檔案。其實這是一種望文生意的錯誤理解。所謂的循序或隨機，不是指資料結構有否結構或次序，而是指我們讀取及使用的方式而言。

循序檔是指資料的讀取或顯示要依資料在檔案內原來的排列次序，不可前後顛倒抽換，一但次序改變資料就會變的不可理解或失去意義，所以一般來說純文字檔、文書檔、繪圖檔、影音檔屬之。

而隨機檔則是指檔案資料的利用是可以加以排列組合或部份抽取，形成一種新的風貌，一般說來資料庫檔案、試算表檔案屬之。

所以任何電腦檔案，如果其資料未事先加以結構化，並在資料輸入時做一種結構的輸入與儲存，則都只能做循序的讀取與利用，也就是說循序是最原始的檔案資料使用型態。只有經過結構化後的檔案資料，才能加以做隨機的讀取與利用。

至於 VB 的循序檔讀取，除了 Random 開檔模式外，其他的開檔模式皆屬循序模式，而用 Input() 方法，Line Input # 陳述式讀入的資料都是循序資料。例外的情況是用Input# 讀 CSV 格式文字檔，可以把循序模式檔案做結構隨機的利用，而用 Byte 變數讀 Random 模式檔案，則又可把隨機檔做循序的利用，中間的分別，則請自行參酌 VB Help 來實測一翻了。

回索引

將 Long Value Color 換成 RGB 值

力天神 撰寫於文章

請問要怎樣把讀取的圖形檔色階轉成三原色???

老怪答：

  1. 要把一個 Long Value 的 Color 值換算成分別的 RGB 值，就要先瞭解分別的 RGB 值是怎樣是怎樣構成一個 Long Value Color 值的。
  2. 一個 Long 型態的數值長度是 4 Byte，1 Byte 數值是從 0~255 ，剛好是分別的 R、G、B 的色數範圍。 但 RGB Color 只用了 3 Byte ，還有 1 Byte 做什麼用呢？也就是一個 Long Value 應該有 32 Bit ，為什麼人家稱全彩卻只有 24 Bit 呢？其實剩下那一 Byte 在標準 Windows Bmp 規格裏是沒有用到的。但在一些特殊的影像處理上卻有用到這多出的 1 Byte，譬如 Targar ( *.tga)圖檔，那多出的 1 Byte 是用來做透明度設定的，也就是從把透明度從完全透明到完全不透明做 0~255 的細分。因此如果以 Long Value 值完全使用的 Tga 圖為例，它的 Color 值組成用 16 進位表示是 &Hrrggbbaa (a 表透明度)。
  3. 既然 BMP 沒用到那最後 1 Byte，我們就不必管透明值了，而一個 Long Value Color 的構成就是 ColorValue=Red+Green*256+Blue*256^2，因此反向拆解這個 Long Value 值，即可得分別的 RGB 值。
  4. '測試本範例請於表單布置 Label1,2,3、Picture1
    Option Explicit

    Private Const cst_REDCOLOR As Byte = 0
    Private Const cst_GREENCOLOR As Byte = 1
    Private Const cst_BLUECOLOR As Byte = 2

    Private Sub Form_Load()
        With Picture1
            .AutoSize = True
            .Picture = LoadPicture("d:\image\01.jpg")
        End With
    End Sub

    Private Function SeperateRGBColor(ByVal LongColor As Long) As Variant
    Dim RGBArray(2) As Byte
        RGBArray(cst_REDCOLOR) = LongColor Mod 256
        LongColor = LongColor / 256
        RGBArray(cst_GREENCOLOR) = LongColor Mod 256
        LongColor = LongColor / 256
        RGBArray(cst_BLUECOLOR) = LongColor Mod 256

        SeperateRGBColor = RGBArray
    End Function

    Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim ColorValue As Long
    Dim AcceptArray As Variant

        ColorValue = Picture1.Point(X, Y)
        '執行 RGB 值之換算函數
        AcceptArray = SeperateRGBColor(ColorValue)

        Label1.Caption = "RED:" & AcceptArray(cst_REDCOLOR)
        Label2.Caption = "GREEN:" & AcceptArray(cst_GREENCOLOR)
        Label3.Caption = "BLUE:" & AcceptArray(cst_BLUECOLOR)
    End Sub

回索引

用 InputB() 快速開中文檔

open filename for input as #1
'以位元組模式開檔
var=InputB(lof(1),#1)
'轉成字元組型態
text1.text=StrConv(var,vbUnicode)

回索引

TextBox 的 Undo 動作模擬

飛鷹 撰寫於文章

請問, 一般的文件編輯器中的 undo 動作, 是如何做成的呢?若我要使用 vb 中的 textbox 如何實作它呢?

老怪答：

Option Explicit

Dim UndoString As String

Private Sub cmdUndo_Click()
    Text1.Text = UndoString
End Sub

Private Sub Text1_KeyDown(KeyCode As Integer, Shift As Integer)
    UndoString = Text1.Text
End Sub

Private Sub Text1_MouseDown(Button As Integer, Shift As Integer, X As
Single, Y As Single)
    UndoString = Text1.Text
End Sub

回索引

如何把字串對齊中央

寄件者: Hong

為何無法把文字顯示在  TextBox 的正中央, 這問題已困擾我很久了,希望能為我解惑。謝謝!

老怪答：

所有的字串對齊都是用 Alignment=2 這個屬性設定中央對齊。不過 TextBox 這個屬性規矩多一點：

  1. 要 TextBox.MultiLine=True 這個屬性才有作用。
  2. Aligement 對 TextBox 來說，只有在設計階段才能設定，在執行階段是唯讀的。

回索引

在固定的集合裡隨機取出數值

路過流浪者 撰寫於文章

如何在VB中要如何在固定的集合裡的數值隨機取出一個，例：
一個集合A，其內容如下:{1,5,8,9,10.2,15,13.5,16}，從A集合中任取一個數。

老怪答：

Option Explicit
Private Sub Command1_Click()
Dim varArray As Variant
    '把集合放到陣列裏
    varArray = Array(1, 5, 8, 9, 10.2, 15, 13.5, 16)
    '1.用亂數產生陣列指標
    '2.用指標參照到集合內的值
    Label1.Caption = varArray(Int(Rnd * (UBound(varArray) + 1)))
End Sub

Private Sub Form_Load()
    '亂數值初始化
    Randomize
End Sub

回索引

偵測控制鍵的事件程序

?? 撰寫於文章

我寫了下面這個程式來試keyascii是多少的值, 但...
Private Sub Form_KeyPress(KeyAscii As Integer)
   Form1.Caption = "You pressed the key: " + CStr(KeyAscii)
End Sub
卻沒辨法請出上下左右等鍵的KeyAscii,請問它們應該是多少?為什麼不能用If KeyAscii=vbKeyLeft等方式來在KeyPress中運作呢?

老怪答：

上下左右等鍵是屬於鍵盤上的控制鍵，鍵盤控制鍵在 VB 中是屬於 KeyCode 這個集合，而不包含在 KeyAscii 集合中，所以無法在 KeyPress 事件程序中偵測，而要在這兩個事件程序中
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)。

回索引

輸出一行多彩字串

飛天企鵝 撰寫於文章

請問VB可以在form有多種顏色的文字嗎??例如說：
我們 要 出去玩
^^^^ ^^ ^^^^^^
<<紅  黃   藍>>

老怪答：

用 ForeColor 屬性去設定 Form 輸出字體顏色是一件很容易的事，但困難的是在一行字串裏輸出多種顏色，所以要讓字串分段輸出，並記得上次輸出的結束位置，以便下一段接在後面的位置，而不是另起一行。程式範例如下：
Private Sub Form_Click()
Dim oldX As Single, oldY As Single
Dim PString As String
    oldY = CurrentY
    oldX = CurrentX

    PString = "我們"
    ForeColor = RGB(255, 0, 0)
    Print PString
    oldX = oldX + TextWidth(PString)

    CurrentX = oldX
    CurrentY = oldY
    PString = "想要"
    ForeColor = RGB(255, 255, 0)
    Print PString
    oldX = oldX + TextWidth(PString)

    CurrentX = oldX
    CurrentY = oldY
    PString = "出去玩"
    ForeColor = RGB(0, 0, 255)
    Print PString

End Sub

回索引

在集合物件中找出特殊設定之子項

時光機器 撰寫於文章

我有一個checkBox的集合項,名為check1，我希望在這個集合項內找出有被選取的子項，該如何做？

老怪答：

Dim Check As CheckBox
    For Each Check In Check1
        If Check.Value Then
            Debug.Print Check.Caption
        End If
    Next

回索引

把圖片從一個表單拖到另一表單

寄件者: king

有沒辦法將一個圖檔從form1拖曳到form2？

老怪答：

這些在表單與表單間用滑鼠拖曳方式交換資料，統稱為 OleDrag 群組命令，是要由好多個事件及方法及範例協同動作的。底下是一個簡單的範例：(由 Form1 向 Form2 拖)
'---------------------
Form1 Code:
'-----------------------------------------------------------
Option Explicit
Private Sub Form_Load()
    Me.Picture = LoadPicture("c:\temp\00.jpg")
    Form2.Show
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single,
Y As Single)
    Me.OLEDrag
End Sub

Private Sub Form_OLEStartDrag(Data As DataObject, AllowedEffects As Long)
    Data.SetData Me.Picture, vbCFBitmap
    AllowedEffects = vbDropEffectCopy
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Unload Form2
End Sub
'--------------------------------------------------------
Form2 Code:
'--------------------------------------------------------
Option Explicit
Private Sub Form_Load()
    Me.OLEDropMode = 1
End Sub

Private Sub Form_OLEDragDrop(Data As DataObject, Effect As Long, Button As
Integer, Shift As Integer, X As Single, Y As Single)
    Set Me.Picture = Data.GetData(vbCFBitmap)
End Sub

回索引

動態陣列的宣告及新增

我竟然是小呆瓜 撰寫於文章

什麼是動態陣列!?這個東西我很難理解..因為我在用ReDim時從來沒有先宣告動態陣列這對程式執行有何影響!?

老怪答：

本來這個問題，是 VB 最基本的入門知識，放在 Tip 裏面真的會被譏為灌水，但在 News Group 裏卻一在有版友問起，心想大概是許多教師或入門書說的很清楚，只好由我再嘮叨一遍，讓還不熟悉的朋友回鍋一下。

  1. 在 VB 中宣告變數分為兩大類：
  2. OK，以上是變數使用的標準方法，但 VB 又提供了一個摸灰的辦法來打破這一切規則，那就是 Variant 型態變數，那就是如果你用
    Dim varName 或
    Dim varName As Variant
    就可以不受這限制了。
  3. 當然如果你程式開頭跟本不要求 Option Explicit(變數非宣告不得使用)，那你不宣告就 Redim 也是可以的，惟一有一點讓我覺得好像是 VB Bug 的是下列的式子居然也可以：
    Option Explicit
    Private Sub Form_Click()
        ReDim varA(10)
        varA(0) = 1
        Print varA(0) + 2
    End Sub
    似乎縱使 varA 不宣告，用 ReDim 仍可以偷溜過關，這實在就違反 Option Explicit 設置目的了。
  4. 不宣告陣列型態而用 Variant 便利性四處闖關，表面上看起來是沒啥害處，但我想 Variant 比其他種型態變數耗用更多的處理時間及記憶體是必然的。所以如果你對程式的要求是過的去即可，那就隨便吧。如果你要求效能更好的話，能宣告別型態變數，就別用 Variant，能用固定陣列就別用變動陣列。

回索引